//处理playing_bar
var playing_obj = new Object();
var playing_listener_obj = new Object();
//初始化广播事件
AsBroadcaster.initialize(playing_obj);
//监听playing_listener_obj
playing_obj.addListener(playing_listener_obj);
//当接收倒playover的广播事件后执行的函数
playing_listener_obj.playover = function() {
    //停在第一帧上
    play_bar.playing_bar.gotoAndStop(1);
    //将当前的img_i加1
    img_i++;
    //如果img_i大于总img数，清零
    if (img_i>img_total) {
        img_i = 0;
    }
    //载入img_arr数组里的图片
    mcLoader.loadClip(img_arr[img_i], empty_mc);
    //去掉所有按钮的高亮，同时设置变量clicked为false
    for (var j = 0; j<=img_total; j++) {
        home["btn_mc_"+j].roll_over_mc._visible = false;
        home["btn_mc_"+j].clicked = false;
    }
    //对当前按钮设置高亮，同时设clicked属性为true
    home["btn_mc_"+img_i].roll_over_mc._visible = true;
    home["btn_mc_"+img_i].roll_over_mc.clicked = true;
};
//接收playstart广播事件，收到事件信息后，play_bar开始播放
playing_listener_obj.playstart = function() {
    home.play_bar.playing_bar.gotoAndPlay(1);
};

//载入外部文件
var mcLoader:MovieClipLoader = new MovieClipLoader();
mcLoader.addListener(this);
function onLoadInit(mc:MovieClip) {
    //载入完后，广播事件playstart
    playing_obj.broadcastMessage("playstart");
    //隐藏loading_txt
    loading_txt._visible = false;
}
this.onLoadProgress = function(target:MovieClip, bytesLoaded:Number, bytesTotal:Number):Void  {
    //显示载入的进度
    loading_txt.text = Math.floor((bytesLoaded/bytesTotal)*100)+"%";
    loading_txt._visible = true;
};

//处理xml
var images_xml:XML = new XML();
images_xml.ignoreWhite = true;
images_xml.onLoad = function(success) {
    //将xml里的元素赋给数组img_arr
    for (var i = 0; i<images_xml.firstChild.childNodes.length; i++) {
        img_arr[i] = images_xml.firstChild.childNodes[i].attributes.src;
    }
    //设置play_bar的位置
    play_bar_pos(i);
   
    //先载入第一个图片
    mcLoader.loadClip(img_arr[img_i], empty_mc);
    //给照片总数赋值
    img_total = --i;
    //分配按钮，并设置按钮的鼠标事件
    attach_btn(img_total);
    //高亮第一个按钮
    home["btn_mc_0"].roll_over_mc._visible = true;
    home["btn_mc_0"].roll_over_mc.clicked = true;
};
//载入xml文件
images_xml.load("images.xml");

//复制按钮
function attach_btn(j) {
    for (var i = 0; i<=j; i++) {
        //将按钮从库里拉出来，并分配坐标
        this.attachMovie("btn_mc", "btn_mc_"+i, this.getNextHighestDepth(), {_x:15+25*i, _y:206});
        //给按钮写上数字，同时隐藏高亮
        with (this["btn_mc_"+i]) {
            num_txt.text = i+1;
            roll_over_mc._visible = false;
        }
        //记录当前的i值
        this["btn_mc_"+i].num = i;
        //鼠标移到mc上面高亮显示
        this["btn_mc_"+i].onRollOver = function() {
            this.roll_over_mc._visible = true;
        };
        //移走后，如果clicked为false，则取消高亮
        this["btn_mc_"+i].onRollOut = function() {
            if (!this.clicked) {
                this.roll_over_mc._visible = false;
            }
        };
        //点击事件
        this["btn_mc_"+i].onRelease = function() {
            //取消所有高亮
            for (var j = 0; j<=img_total; j++) {
                home["btn_mc_"+j].roll_over_mc._visible = false;
                home["btn_mc_"+j].clicked = false;
            }
            //设置当前高亮
            this.roll_over_mc._visible = true;
            this.clicked = true;
            //播放条停在第一帧
            play_bar.playing_bar.gotoAndStop(1);
            载入相应的图片或swf
            mcLoader.loadClip(img_arr[this.num], empty_mc);
            //设置当前的img_i
            img_i = this.num+1;
            //trace(this.num);
        };
    }
}

//设置play_bar的位置
function play_bar_pos(k){
    k--;
    play_bar._x = 15+25*k+30;
    play_bar._y = 210;
}